Liste der Elemente in Envision - Software zur Bestandsoptimierung

Liste der Elemente












Startseite » Ressourcen » Hier

Die Elemente stellen den Grundbaustein der Dashboards in Envision dar. Im Folgenden werden alle Elemente, die von Envision unterstützt werden, angeführt.


Syntax der Elemente

Die generische Inline-Syntax für Elemente ist:
show table "hello" a1c2 tomato with
 x
 sum(y)
 avg(z)
 group by [x,a]
 order by [max(y), b] desc
Das erste Argument nach dem Namen des Elements (table oben) ist die Überschrift, title, des Elements. Nach der Überschrift steht die Position und Größe innerhalb des Dashboards, die in Anlehnung an eine Excel-Tabelle codiert ist (Buchstaben geben Spalten an und Zahlen Zeilen). Zum Schluss wird die Farbe entweder als Webfarbe oder mit dem Hexadezimalcode ohne das Zeichen # (z.B. FF6347 für tomato) angegeben.

  • Die meisten Elemente können mehrere Argumente nach dem Schlüsselwort with übergeben.
  • Die Anweisung group by ist optional und unterstützt mehrere Ausdrücke. Wird group by benutzt, sollten die Ausdrücke Aggregatoren zur Verfügung stellen, außer sie sind bereits voraggregiert.
  • Die Anweisung order by ist optional und unterstützt auch mehrere Ausdrücke. Die Anweisung desc kann weggelassen werden. Ist sie vorhanden, wird die Bestellung in absteigender Reihenfolge durchgenommen.

Die Ausdrücke, die als Argumente nach dem with übergeben werden, werden von Envision automatisch ausgerichtet, um die Eingabedaten als Tabelle für das Element zu behandeln. Diese Eingabetabelle kann mit folgender Syntax exportiert werden:
show table "hello" a1c2 tomato export:"/mytable.tsv" with x, y, z
Dabei werden die Dateiformate CSV, TSV, XLSX (Excel) und RFF (raw flat file) unterstützt. Sollte die angegebene Dateiendung unbekannt sein, wird der Export fehlschlagen.

Es können auch Elemente in zwei - oder mehr - Speicherorte gleichzeitig exportiert werden, indem mehrere export-Anweisungen benutzt werden:
show table "hello" a1c2 tomato export:"/foo1.tsv" export:"/foo2.tsv" with x, y, z
In der Praxis bietet Envision, da Anweisungen für Elemente generell lang sind, eine Block-Syntax für Elemente mit:
show table "hello" a1c2 tomato export:"/foo1.tsv" export:"/foo2.tsv" with
 x as "My Name" 
 sum(y) as "My total" unit: "$"
 avg(z)
 group by [x,a]
 order by [max(y), b]

Farben als Runtime-Option

Die kompakte Inline-Syntax für die Farbe der Elemente hat einen Nachteil: Sie können nicht durch Programmierung die Farben bestimmen. Envision bietet Ihnen die Möglichkeit, Farben als benannte Option zu wählen:
isMonday := today() mod 7 == 0
myColor := isMonday ? "black" : "red"
show label "Monday is Black" color: myColor
Die Option color erwartet einen skalaren Textwert. Im oberen Beispiel ändert sich die Farbe des Elements nach den Tag. Montags ist es Schwarz und an allen anderen Tagen Rot.

assert-Element

Dieses Element ist absichtlich dazu konzipiert, als failed (fehlgeschlagen) ausgeführt zu werden, wenn bestimmte Bedingungen bei den Daten nicht erfüllt werden. Die Liste der Bedingungen kann nach dem Schlüsselwort with angeführt werden.

show assert "My flags" with
 count(Id) > 20 as "More than 20 items found"
 sum(Orders.1) > 20 as "More than 20 orders found"

Balkendiagramm-Element

Dieses Element soll ein Liniendiagramm anzeigen. Der Ausdruck, der nach dem Schlüsselwort with übergeben wird, sollte einen Aggregator bieten. Es wird eine explizite Anweisung group by erwartet.
show barchart "Stock per Brand" unit: "$" with
 sum(StockOnHand * PurchasePrice)
 group by Brand

Folgende Optionen sind auf Element-Ebene verfügbar:
  • color (skalarer Text): Grundfarbe zum Zeichnen der Balken.
  • download (skalarer Text): Name der Datei, wenn das Element vom Dashboard heruntergeladen wird.
  • export (skalarer Text): Der lokale Name der Datei, in der der Inhalt des Elements erwartet wird.
  • unit (skalarer Text): Die standardmäßige Einheit, die numerischen Werten zugeordnet wird.

Es sind keine Spaltenoptionen zulässig.

Formular-Element

Dieses Element soll ein Formular anzeigen, in das die Werte manuell aus der Dashboard-Ansicht eingetragen werden können. Die Variablen, die für die Anzeige gelistet werden, sollten der virtuellen Form Tabelle zugeordnet sein.
show form "My settings" with
 Form.myValue as "My Value"
 Form.secondValue as "Second Value"
In Formularen definierte Variablen sind immer skalar. Ihr skalarer Typ wird von ihrer Nutzung im Skript abgeleitet. Es ist möglich, mehrere Variablen im Formular anzugeben. Als Faustregel empfehlen wir, eine Höhe (Anzahl der Tabellenzeilen, die gedeckt werden sollen) anzugeben, die gleich N+1 ist, wobei N die Anzahl der im Form nach dem with eingegebenen Variablen ist.

Histogramm-Element

Dieses Element ist für die Anzeige eines Histogramms gedacht. Im Gegensatz zum barchart (Balkendiagramm), sind die Säulen des Histogramms senkrecht ausgerichtet. Das Histogramm-Element erwartet einen einzigen numerischen Vektor als Argument.
show histogram "Quantities ordered" with
 Orders.Quantity
Außerdem kann das Histogramm-Element auch zur Anzeige einer skalaren Verteilung benutzt werden:
show histogram "Poisson Law" with poisson(3)
Wenn Sie eine probabilistische Vorhersage für den Bedarf erstellt haben, muss ein einzelner Artikel gewählt werden. Dies können Sie, wie folgt, erreichen:
where Id == "123"
 show histogram "My Forecast" with same(Demand)

Auf Elementebene sind folgende Optionen verfügbar:
  • color (skalarer Text): Grundfarbe, die für das Histogramm benutzt werden soll.
  • unit (skalarer Text): Die standardmäßige Einheit, die numerischen Werten zugeordnet wird.

Es sind keine Spaltenoptionen zulässig.

Überschrift-Element

Dieses Element soll einen Text im Dashboard anzeigen. Dies ist das einfachste Element, das keiner Eingabedaten bedarf.
show label "Hello World"

Liniendiagramm-Element

Dieses Element zeigt Zeitreihen an. Dieses Element nutzt nach Datum indexierte Daten als Eingabe. Nach dem Schlüsselwort with können mehrere Ausdrücke als Argument übergeben werden.
Week.sold := sum(Orders.NetAmount)
show linechart "Week sold/purchased" unit: "$" with
 Week.sold as "Sold" color: "red"
 sum(PO.NetAmount) color: "blue"
Während die Farbe auf Element-Ebene definiert werden kann, wie bei jedem anderen Element, ist es auch möglich, die Farbe für jede Linie, die gezeichnet werden soll, einzeln festzulegen, wie oben gezeigt wird.

Auf Elementebene sind folgende Optionen verfügbar:

  • color (skalarer Text): Grundfarbe, die zum Zeichnen der ersten Linie benutzt wird.
  • unit (skalarer Text): Die standardmäßige Einheit, die für numerische Werte genutzt wird.

Auf Spaltenebene sind folgende Optionen verfügbar:
  • color (skalarer Text): Grundfarbe, die zum Zeichnen der Linie, die der Spalte zugeordnet wird, benutzt wird.
  • unit (skalarer Text): es kann eine zweite Einheit definiert werden. Wenn eine zweite Einheit definiert ist, bieten sowohl die linke als auch die rechte Y-Achse Gradienten .

Logo-Element

Dieses Element dient der Anzeige des Firmenlogos. Das Element zeigt die Datei logo.png oder logo.jpg an, die sich im Hauptverzeichnis Ihres Lokad-Kontos befinden sollte. Falls Sie noch keine Datei mit dem Logo hochgeladen haben, schlägt Ihnen dieses Element vor, dies zu tun. Dabei sollte das Bild 150x70px (eine Spalte breit) oder 310x70px (zwei Spalten breit) sein.
show logo "My Company"

Markdown-Element

In diesem Element wird Kontextinformation angezeigt, die in Markdown, formatiert ist, einer sehr einfachen Auszeichnungssprache, die Ihnen hilft, ein im Web lesbares Dokument zu erstellen.
show markdown "My title" a6h6 with """
# Part A
## Subpart A.1
A list of **important** remarks.

* remark 1
* remark 2
* remark 3

## Subpart A.2
# Part B

Less important remarks.
"""  

Wir empfehlen Ihnen, das Überschrift-Element leer zu lassen, da es gewöhnlich redundant ist, wenn die Überschrift im Markdown-Abschnitt selbst definiert ist, wie durch Folgendes verdeutlicht wird:
show markdown "" with """ ... """

Tortendiagramm-Element

Dieses Element soll ein Tortendiagramm anzeigen. Der nach dem with Schlüsselwort übergebene Ausdruck sollte einen Aggregator anbieten. Es wird eine explizite group by Anweisung erwartet.
show piechart "Stock per Brand" unit: "$" with
 sum(StockOnHand * PurchasePrice)
 group by Brand

Zeichnungs-Element

Dieses Element sollt eine Funktion f(x)=y anzeigen.
show plot "My function" with T.X, T.Y

Die verfügbaren Optionen auf Elementebene sind folgende:
  • color (skalarer Text): Grundfarbe, die zur Anzeige der gezeichneten Linie benutzt wird.
  • unit (skalarer Text): Die standardmäßige Einheit, die für numerische Werten genutzt wird.

Zusammenfassungs-Element

In diesem Element sammeln Sie verschiedene Skalarwerte, gewöhnlich KPIs. Dabei kann jeder Wert einer Überschrift und einer Einheit zugeordnet werden.
show summary "Key stock figures" a1b2 with
 sum(StockOnHand) as "Units on hand"
 sum(StockOnOrder) as "Units on order"
 sum(Stock * BuyPrice) as "Stock value" unit: "$"

Tabellen-Element

Das table Element, ist das vielseitigste Element in Envision. Dieses Element soll eine Tabelle anzeigen, die optional als Flatfile exportiert werden kann.
show table "Top sellers" export:"/tops.tsv" with
 Supplier as "Supplier Name"
 Category as "Category"
 sum(Orders.NetAmount) as "Sold" unit:"$"
 group by [Supplier, Category]
 order by sum(Orders.NetAmount) desc

Das Tabellen-Element unterstützt sowohl die group by als auch die order by Aggregationsoptionen. In beiden Fällen kann ein Tupel statt einem einzelnen Wert zurückgegeben werden.

Optionen auf Elementebene

Das Tabellen-Element unterstützt mehrere Optionen, die als Elementeben definiert werden. Diese Optionen werden nach der Überschrift angegeben, wie Sie hier sehen können:
show table "options" color: "red" unit: "$" with 123

Folgende Liste beinhaltet die verfügbaren Optionen:

  • color (skalarer Text): Grundfarbe, die für das Element benutzt wird.
  • date (skalarer Text): Das standardmäßige Datumsformat für Datumsspalten (sehen Sie weiter unten die Formatvorgaben).
  • download (skalarer Text): standardmäßiger Name der Datei, wenn das Element von einem Benutzer vom Dashboard heruntergeladen wird.
  • export (skalarer Text): Der Pfad der Datei, in dem der Inhalt der Tabelle im Lokad-Konto gespeichert wird. Zum Beispiel "export: "/foo/bar.csv". Es ist auch zulässig, mehrere export-Optionen zu schreiben, dann werden entsprechend mehrere Exporte erstellt.
  • numbers (skalarer Text): Das standardmäßige Zahlenformat für numerische Spalten (sehen Sie weiter unten die Formatvorgaben).
  • precision (skalare Zahl): Definieren Sie, wie viele Nachkommastellen in numerischen Spalten angezeigt werden.
  • quotes (skalares Boolean): Wenn true, werden die Daten in den generierten CSV- oder TSV-Dateien mit Anführungszeichen versehen. Der Standardwert ist false.
  • unit (skalarer Text): Die standardmäßige Einheit, die bei der Anzeige von numerischen Werten benutzt wird.

Optionen auf Spaltenebene

Sie profitieren von verschiedenen Optionen für jede Spalte, wie Sie an dieser Syntax erkennen können:
show table "Some column-level options" with
 Id as "Produce ID"
 StockOnHand as "On Hand" unit: "ea"
 BuyPrice unit: "$"

Diese Liste enthält alle Spaltenoptionen:
  • date (skalarer Text): Das Datumsformat für diese Spalte (sehen Sie weiter unten die Formatvorgaben).
  • display (skalares Boolean): Gibt an, ob eine Spalte im Dashboard angezeigt wird. Der Standardwert ist true. Es kann von Vorteil sein, eine Spalte nicht anzuzeigen, wenn man diese Spalte nur in eine Datei exportieren will.
  • export (skalares Boolean): Gibt an, ob die Spalte in eine Datei exportiert wird. Der Standardwert ist true. Es kann von Vorteil sein, eine Spalte nicht zu exportieren, wenn Sie nur im Dashboard angezeigt werden soll.
  • numbers (skalarer Text): Das standardmäßige Zahlenformat für numerische Spalten (sehen Sie weiter unten die Formatvorgaben).
  • precision (skalare Zahl): Definieren Sie, wie viele Nachkommastellen in numerischen Spalten angezeigt werden.
  • quotes (skalares Boolean): Wenn true, werden die Daten in den generierten CSV- oder TSV-Dateien mit Anführungszeichen versehen. Der Standardwert ist false.
  • unit (skalarer Text): Die Einheit, die bei der Anzeige von numerischen Werten für die Spalte benutzt wird.

Zeichenfolge für Datumsformat

Die Zeichenfolge für die Datumsangabe stellt eine kleine Syntax dar, durch die Sie festlegen können, wie das Datum im Tabellen-Element formatiert werden soll. Zum Beispiel:
show table "Last sold" date: "yyyy-MM-dd" with
 max(Orders.Date)

Folgende Tokens sind verfügbar:

  • d: Tag des Monats von 1 bis 31
  • dd: Gleich wie d aber mit einer 0 vorne
  • ddd: Abkürzung für den Wochentag (z.B.: Mon, Tue...)
  • dddd: Ganzer Wochentag (Monday...)
  • MM: Monatszahl von 1 bis 12.
  • MMM: Abgekürzter Monatsname (z.B.: Jan, Feb, ...)
  • MMMM: Ganzer Monatsname (June)
  • yy: Jahreszahl von 00 bis 99, wobei die Tausender- und Hunderterstellen nicht berücksichtigt werden.
  • yyyy: Jahr mit vier Zahlen.

Jegliche andere Zeichen werden wie sie sind im der Ausgabezeichenfolge benutzt.

Zeichenfolge für Zahlenformat

Die Zeichenfolge für die Zahlen stellt eine kleine Syntax dar, durch die Sie festlegen können, wie die Zahlen im Tabellen-Element formatiert werden sollen. Zum Beispiel:
show table "Total sold" number:"1,000.00" with
 sum(Orders.NetAmount)

Diese Syntax ahmt die eigentliche erwünschte Ausgabe der Zahlen nach:
  • Das Zeichen nach der anfänglichen 1 dient als Tausendertrennzeichen. Es kann ausgelassen werden.
  • Das Zeichen von den letzten Nullen dient als Zehnertrennzeichen. Es kann ausgelassen werden.

Einzelwertanzeige

Wenn ein table-Element nur eine einzelne Spalte und eine einzige Zeile beinhaltet, wird die Tabellenanzeige angepasst, um eine Einzelwertanzeige wiederzuspiegeln.
show table "Total Stock Value" with
 sum(StockOnHand * BuyPrice)

Treemap-Element

Das treemap Element zeigt ein Tree Map an. Tree Maps dienen dazu, die entsprechenden Gewichte der Elemente innerhalb eines potentiell großen Datasets besser zu verstehen. Dieses Element erwartet zwei Argumente: zuerst das label, als zweites das value. Dann wird erwartet, dass eine Gruppierung durch die group by Anweisung spezifiziert wird.
show treemap "Stock Value" with
 Name
 StockOnHand * PurchasePrice
 group by Category
Die Zellen, die vom Tree Map angezeigt werden, sind proportional zur Summe der Werte.